[xiph-commits] r9702 - in trunk/theora: . m4

[conrad at svn.xiph.org]

Author: conrad
Date: 2005-08-05 02:52:02 -0700 (Fri, 05 Aug 2005)
New Revision: 9702

Added:
   trunk/theora/m4/
   trunk/theora/m4/as-ac-expand.m4
Modified:
   trunk/theora/autogen.sh
   trunk/theora/configure.ac
Log:
add configuration summary to ./configure output


Modified: trunk/theora/autogen.sh
===================================================================
--- trunk/theora/autogen.sh	2005-08-05 06:43:12 UTC (rev 9701)
+++ trunk/theora/autogen.sh	2005-08-05 09:52:02 UTC (rev 9702)
@@ -22,6 +22,8 @@
 
 VERSIONGREP="sed -e s/.*[^0-9\.]\([0-9]\.[0-9]\).*/\1/"
 VERSIONMKINT="sed -e s/[^0-9]//"
+
+ACLOCAL_FLAGS="-I m4"
                                                                                 
 # do we need automake?
 if test -r Makefile.am; then

Modified: trunk/theora/configure.ac
===================================================================
--- trunk/theora/configure.ac	2005-08-05 06:43:12 UTC (rev 9701)
+++ trunk/theora/configure.ac	2005-08-05 09:52:02 UTC (rev 9702)
@@ -39,6 +39,9 @@
 
 AM_PROG_LIBTOOL
 
+dnl Add parameters for aclocal
+AC_SUBST(ACLOCAL_AMFLAGS, "-I m4")
+
 dnl Check for doxygen
 AC_CHECK_PROG(HAVE_DOXYGEN, doxygen, true, false)
 AM_CONDITIONAL(HAVE_DOXYGEN,$HAVE_DOXYGEN)
@@ -267,3 +270,36 @@
   theora.pc
   theora-uninstalled.pc
 ])
+
+AS_AC_EXPAND(LIBDIR, ${libdir})
+AS_AC_EXPAND(INCLUDEDIR, ${includedir})
+AS_AC_EXPAND(BINDIR, ${bindir})
+AS_AC_EXPAND(DOCDIR, ${datadir}/doc)
+
+AC_MSG_RESULT([
+------------------------------------------------------------------------
+  $PACKAGE $VERSION:  Automatic configuration OK.
+
+  General configuration:
+
+    Encoding support: ............ ${ac_enable_encode}
+    Floating point support: ...... ${ac_enable_float}
+
+  Installation paths:
+
+    libtheora: ................... ${LIBDIR}
+    C header files: .............. ${INCLUDEDIR}/theora
+    Documentation: ............... ${DOCDIR}/$PACKAGE
+
+  Building:
+
+    Type 'make' to compile $PACKAGE.
+
+    Type 'make install' to install $PACKAGE.
+
+    ${TESTS_INFO}
+
+  Example programs will be built but not installed.
+------------------------------------------------------------------------
+])
+

Added: trunk/theora/m4/as-ac-expand.m4
===================================================================
--- trunk/theora/m4/as-ac-expand.m4	2005-08-05 06:43:12 UTC (rev 9701)
+++ trunk/theora/m4/as-ac-expand.m4	2005-08-05 09:52:02 UTC (rev 9702)
@@ -0,0 +1,43 @@
+dnl as-ac-expand.m4 0.2.0
+dnl autostars m4 macro for expanding directories using configure's prefix
+dnl thomas at apestaart.org
+
+dnl AS_AC_EXPAND(VAR, CONFIGURE_VAR)
+dnl example
+dnl AS_AC_EXPAND(SYSCONFDIR, $sysconfdir)
+dnl will set SYSCONFDIR to /usr/local/etc if prefix=/usr/local
+
+AC_DEFUN([AS_AC_EXPAND],
+[
+  EXP_VAR=[$1]
+  FROM_VAR=[$2]
+
+  dnl first expand prefix and exec_prefix if necessary
+  prefix_save=$prefix
+  exec_prefix_save=$exec_prefix
+
+  dnl if no prefix given, then use /usr/local, the default prefix
+  if test "x$prefix" = "xNONE"; then
+    prefix="$ac_default_prefix"
+  fi
+  dnl if no exec_prefix given, then use prefix
+  if test "x$exec_prefix" = "xNONE"; then
+    exec_prefix=$prefix
+  fi
+
+  full_var="$FROM_VAR"
+  dnl loop until it doesn't change anymore
+  while true; do
+    new_full_var="`eval echo $full_var`"
+    if test "x$new_full_var" = "x$full_var"; then break; fi
+    full_var=$new_full_var
+  done
+
+  dnl clean up
+  full_var=$new_full_var
+  AC_SUBST([$1], "$full_var")
+
+  dnl restore prefix and exec_prefix
+  prefix=$prefix_save
+  exec_prefix=$exec_prefix_save
+])