[xiph-cvs] cvs commit: m4 xiph_xml2.m4

[Karl Heyes]

karl        03/07/17 06:46:03

  Modified:    .        configure.in
  Added:       .        xiph_xml2.m4
  Log:
  move xml/xslt detection into the m4 tree

Revision  Changes    Path
1.31      +1 -24     ices/configure.in

Index: configure.in
===================================================================
RCS file: /usr/local/cvsroot/ices/configure.in,v
retrieving revision 1.30
retrieving revision 1.31
diff -u -r1.30 -r1.31
--- configure.in	11 Jul 2003 01:26:17 -0000	1.30
+++ configure.in	17 Jul 2003 10:46:03 -0000	1.31
@@ -96,30 +96,7 @@
 
 dnl Checks for library functions.
 
-dnl deal with xml-config
-AC_MSG_RESULT([checking for XML configuration])
-AC_ARG_VAR([XMLCONFIG],[XML configuration program])
-AC_ARG_WITH(xml-config,
-    [AC_HELP_STRING([--with-xml-config=PATH],
-                    [use xml-config in PATH to find libxml])],
-    [XMLCONFIG="$withval"],
-    [AC_PATH_PROGS(XMLCONFIG, [xml2-config xml-config], "")]
-)
-if test "x$XMLCONFIG" = "x"; then
-    AC_MSG_ERROR([XML configuration could not be found])
-fi
-if ! test -x "$XMLCONFIG"; then
-    AC_MSG_ERROR([$XMLCONFIG cannot be executed])
-fi
-XML_LIBS="$($XMLCONFIG --libs)"
-XML_CFLAGS="$($XMLCONFIG --cflags)"
-ac_save_LIBS="$LIBS"
-ac_save_CFLAGS="$CFLAGS"
-LIBS="$XML_LIBS $XIPH_LIBS"
-CFLAGS="$XIPH_CFLAGS $XML_CFLAGS"
-AC_CHECK_FUNC(xmlParseFile,, [AC_MSG_ERROR([There was a problem linking with libxml])])
-CFLAGS="$ac_save_CFLAGS"
-LIBS="$ac_save_LIBS"
+XIPH_PATH_XML
 XIPH_VAR_APPEND([XIPH_CFLAGS], [$XML_CFLAGS])
 XIPH_VAR_PREPEND([XIPH_LIBS], [$XML_LIBS])
 

<p><p>1.1                  m4/xiph_xml2.m4

Index: xiph_xml2.m4
===================================================================
dnl XIPH_PATH_XML
dnl Populate XML_CFLAGS and XML_LIBS with infomation for
dnl linking with libxml2
AC_DEFUN([XIPH_PATH_XML],
[dnl
AC_MSG_RESULT([checking for XML configuration])
AC_ARG_VAR([XMLCONFIG],[XML configuration program])
AC_ARG_WITH(xml-config,
    [AC_HELP_STRING([--with-xml-config=PATH],
                    [use xml-config in PATH to find libxml])],
    [XMLCONFIG="$withval"],
    [AC_PATH_PROGS(XMLCONFIG, [xml2-config xml-config], "")]
)
if test "x$XMLCONFIG" = "x"; then
    AC_MSG_ERROR([XML configuration could not be found])
fi
if ! test -x "$XMLCONFIG"; then
    AC_MSG_ERROR([$XMLCONFIG cannot be executed])
fi
XML_LIBS="$($XMLCONFIG --libs)"
XML_CFLAGS="$($XMLCONFIG --cflags)"
ac_xml_save_LIBS="$LIBS"
ac_xml_save_CFLAGS="$CFLAGS"
LIBS="$XML_LIBS $LIBS"
CFLAGS="$CFLAGS $XML_CFLAGS"
AC_CHECK_FUNC(xmlParseFile,, [AC_MSG_ERROR([Unable to link with libxml])])
CFLAGS="$ac_xml_save_CFLAGS"
LIBS="$ac_xml_save_LIBS"
])

dnl XIPH_PATH_XSLT
dnl Populate XSLT_CFLAGS and XSLT_LIBS with infomation for
dnl linking with libxml2
AC_DEFUN([XIPH_PATH_XSLT],
[dnl
AC_ARG_VAR([XSLTCONFIG],[XSLT configuration program])
AC_ARG_WITH(xslt-config,
    [AC_HELP_STRING([--with-xslt-config=PATH],
                    [use xslt-config in PATH to find libxslt])],
    [XSLTCONFIG="$withval"],
    [AC_PATH_PROGS(XSLTCONFIG, [xslt-config], "")]
)
if test "x$XSLTCONFIG" = "x"; then
    AC_MSG_ERROR([XSLT configuration could not be found])
fi
if ! test -x "$XSLTCONFIG"; then
    AC_MSG_ERROR([$XSLTCONFIG cannot be executed])
fi
XSLT_LIBS="$($XSLTCONFIG --libs)"
XSLT_CFLAGS="$($XSLTCONFIG --cflags)"
ac_xslt_save_LIBS="$LIBS"
ac_xslt_save_CFLAGS="$CFLAGS"
LIBS="$XSLT_LIBS $LIBS"
CFLAGS="$CFLAGS $XSLT_CFLAGS"
AC_CHECK_FUNC(xsltParseStylesheetFile,,[AC_MSG_ERROR([Unable to link with libxslt])])
CFLAGS="$ac_xslt_save_CFLAGS"
LIBS="$ac_xslt_save_LIBS"
])

<p><p>--- >8 ----
List archives:  http://www.xiph.org/archives/
Ogg project homepage: http://www.xiph.org/ogg/
To unsubscribe from this list, send a message to 'cvs-request at xiph.org'
containing only the word 'unsubscribe' in the body.  No subject is needed.
Unsubscribe messages sent to the list will be ignored/filtered.